Quick Start: Foundry

Set up a Foundry project with @cofhe/foundry-plugin, write a contract that stores an encrypted uint32, and test the encrypt to store to decrypt flow under forge test.

Want to skip the setup? Clone the cofhe-foundry-starter template to get a pre-configured project with everything ready to go.

Prerequisites

Foundry (forge, cast, anvil)
Node.js 18+ with npm/pnpm/yarn (for installing the plugin’s npm packages)

1. Install dependencies

The plugin and its CoFHE dependencies are distributed via npm. Install them as dev dependencies, then forge install for forge-std:

npm install -D @cofhe/foundry-plugin@^0.7.1 @cofhe/mock-contracts@^0.7.1 @fhenixprotocol/cofhe-contracts@^0.2.0 @openzeppelin/contracts
forge install foundry-rs/forge-std

pnpm add -D @cofhe/foundry-plugin@^0.7.1 @cofhe/mock-contracts@^0.7.1 @fhenixprotocol/cofhe-contracts@^0.2.0 @openzeppelin/contracts
forge install foundry-rs/forge-std

yarn add -D @cofhe/foundry-plugin@^0.7.1 @cofhe/mock-contracts@^0.7.1 @fhenixprotocol/cofhe-contracts@^0.2.0 @openzeppelin/contracts
forge install foundry-rs/forge-std

2. Configure `foundry.toml`

foundry.toml

[profile.default]
src = "src"
out = "out"
test = "test"
script = "script"
libs = ["node_modules"]
solc_version = "0.8.25"
auto_detect_remappings = false
code_size_limit = 100000

code_size_limit = 100000 is required, the mock contracts exceed the EIP-170 24 KB limit.

evm_version = "cancun" is no longer required as of @cofhe/mock-contracts@0.7.1. MockACL was migrated off transient storage to block-number-based storage. Set it only if your own contracts need cancun-specific opcodes.

3. Configure `remappings.txt`

remappings.txt

forge-std/=node_modules/forge-std/src/
hardhat/=node_modules/forge-std/src/
@openzeppelin/contracts/=node_modules/@openzeppelin/contracts/
@fhenixprotocol/cofhe-contracts/=node_modules/@fhenixprotocol/cofhe-contracts/
@cofhe/mock-contracts/=node_modules/@cofhe/mock-contracts/
@cofhe/foundry-plugin/=node_modules/@cofhe/foundry-plugin/

The hardhat/=node_modules/forge-std/src/ line is load-bearing. MockCoFHE.sol imports hardhat/console.sol, and this alias resolves it to forge-std’s compatible console.sol.

4. Write a contract

src/MyContract.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import "@fhenixprotocol/cofhe-contracts/FHE.sol";

contract MyContract {
    euint32 public storedValue;

    function setValue(externalEuint32 inValue, bytes calldata inputProof) external {
        storedValue = FHE.asEuint32(inValue, inputProof);
        FHE.allowThis(storedValue);
        FHE.allowSender(storedValue);
    }
}

euint32: an encrypted uint32 stored onchain as a ciphertext handle.
externalEuint32: the encrypted input handle produced by CofheClient, paired with a bytes proof.
FHE.allowThis / FHE.allowSender: grant the contract and caller permission to read the encrypted value (required by the ACL).

5. Write a test

test/MyContract.t.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import { CofheTest } from "@cofhe/foundry-plugin/contracts/CofheTest.sol";
import { CofheClient } from "@cofhe/foundry-plugin/contracts/CofheClient.sol";
import { externalEuint32 } from "@fhenixprotocol/cofhe-contracts/FHE.sol";
import { MyContract } from "../src/MyContract.sol";

contract MyContractTest is CofheTest {
    MyContract public myContract;
    CofheClient public bob;

    uint256 constant BOB_PKEY = 0xB0B;

    function setUp() public {
        deployMocks();

        bob = createCofheClient();
        bob.connect(BOB_PKEY);

        vm.prank(bob.account());
        myContract = new MyContract();
    }

    function test_StoresAndDecryptsAnEncryptedValue() public {
        // 1. Encrypt the input, bound to the contract that will consume it
        (externalEuint32 hash, bytes memory proof) = bob.createExternalEuint32(42, address(myContract));

        // 2. Send to contract
        vm.prank(bob.account());
        myContract.setValue(hash, proof);

        // 3. Assert the stored plaintext directly (mock-only, no ACP needed)
        expectPlaintext(myContract.storedValue(), uint32(42));
    }
}

6. Run

forge test -vvv

[PASS] test_StoresAndDecryptsAnEncryptedValue() (gas: …)

Test result: ok. 1 passed; 0 failed; 0 skipped; finished in …

What just happened?

deployMocks() deployed the full CoFHE coprocessor mock stack (TaskManager, ACL, ZK verifier, threshold network) to the in-process EVM.
createCofheClient() + bob.connect(BOB_PKEY) spun up an in-Solidity SDK shim bound to vm.addr(BOB_PKEY).
bob.createExternalEuint32(42, address(myContract)) produced a signed externalEuint32 and its proof, the same shape your contract receives on testnet, signed by MockZkVerifierSigner.
vm.prank(bob.account()) + setValue(...) called the contract as Bob. The contract stored the ciphertext handle and granted ACL access to itself and Bob.
expectPlaintext(myContract.storedValue(), 42) read the onchain plaintext directly from MockTaskManager.mockStorage, no ACP, no SDK round-trip.

Next steps

Foundry Plugin to Getting Started: full plugin configuration and features.
CofheTest: deployMocks, expectPlaintext, log toggles.
CofheClient: encrypt inputs, decrypt for view or tx, and ACPs.
Testing: canonical test patterns for ACL, public-decrypt, and fuzzing.

Introduction

Quick Start

Guides

Hardhat Plugin

Foundry Plugin

Examples

Reference

Prerequisites

1. Install dependencies

2. Configure `foundry.toml`

3. Configure `remappings.txt`

4. Write a contract

5. Write a test

6. Run

What just happened?

Next steps

​Prerequisites

​1. Install dependencies

​2. Configure foundry.toml

​3. Configure remappings.txt

​4. Write a contract

​5. Write a test

​6. Run

​What just happened?

​Next steps

Prerequisites

1. Install dependencies

2. Configure `foundry.toml`

3. Configure `remappings.txt`

4. Write a contract

5. Write a test

6. Run

What just happened?

Next steps